begintownscript;
variables;
short choice,i,erase;

body;
beginstate init_state;
i = 0;
while(char_ok(i) == 0){
	i = i + 1;
}
set_character_pose(i,6);
set_name(28,"Innkeeper");
set_char_dialogue_pic(28,1959,0);
set_ticks_forward(4100 - get_current_tick());
relocate_character(i,14,8);
message_dialog("I don't remember much of what happened after that. When I came to I was sitting in a chair-- at an inn. I had no idea how I got there. There was a bowl of soup in my hands-- it was half eaten. I had no idea how that got there.","My head was gradually beginning to clear. Everything around me was no longer terrifying, but it was somewhat blurry nonetheless. Whenever I quickly turned my head the room would spin, and I had a splitting headache.");
message_dialog("Outside I could see that it was night. The toxin must have been a particularly potent one to keep me dazed for so long. Most of the inn's customers had already gone home, except a few stragglers and a shady group of men at a nearby table.","The innkeeper came over to check on me and refill my bowl of soup. I asked her what was going on.");
break;

beginstate exit_state;
break;

beginstate start_state;
if((get_flag(9,0) > 0) && (num_chars_in_group(1) == 0) && (get_flag(9,2) == 0)){
	set_flag(9,2,1);
	message_dialog("Scrubs.","");
}
break;

beginstate 10;
if(get_flag(9,0) == 0)
	block_entry(1);
else
	end();
if(get_flag(9,1) > 0){
	erase = 6;
	while(erase <= 119){
		if(creature_type(erase) == 7)
			erase_char(erase);
		erase = erase + 1;
	}
	message_dialog("I leapt to my feet, causing the bowl of soup to crash to the floor and my head to spin. A heavy hand on my shoulder forced me back down to the seat.","I looked up to find that I was surrounded by the group of men that had occupied the nearby table.");
	activate_hidden_group(2);
	force_instant_terrain_redraw();
	pause(3);
	message_dialog("_Not so fast, little fellow. Your friend there had quite a handsome coin purse. Me and the boys here thought you might help us get a hold of it._ One of the other bandits snickered. The speaker's hand lingered on my shoulder, pressing me down.","_Said he'd come by to check on you, and pay Margaret here the other half of her money. That's good-- that's fine-- but we was thinking we'd maybe take the rest of it, for providing such good protection for ye while you were sick._");
	message_dialog("_You're just going to have to stay put for a while. Oh-- I like that bracelet you have there, mind if I have a quick..._","");
	message_dialog("I didn't have time for this bullshit, an extremely valuable package was lying in the road somewhere, and I couldn't rest until I had it.","I took a deep breath to try to clear my head. Then struck.");
	play_sound(72);
	message_dialog("I struck the bandit's wrist, and was rewarded with the sound of snapping bone. He recoiled and howled with pain, cradling his ruined hand.","His fellows put up a shout and drew their weapons. Foggy head or no, I had a fight on my hands.");
	set_char_status(i,1,-20,1,0);
	set_character_pose(i,2);
	force_instant_terrain_redraw();
	set_flag(9,0,1);
}
break;

beginstate 12;
	block_entry(1);
	message_dialog("I had more important things to do. Namely find that package before somebody else did.","");
break;

beginstate 13;
if(get_flag(9,2) == 0)
	block_entry(1);
else
	if(get_flag(9,3) == 0){
		set_flag(9,3,1);
		message_dialog("From the outside I recognized this inn from earlier this morning. I'd passed it on my way to Cigosal, which meant that whoever my savior was, he'd taken me further from my destination.","I had my bearings at least. The cart and the package were to the east.");
	}
break;

beginstate 14;
move_to_new_town(8,2,14);
//move_to_new_town(0,2,14);
break;

beginstate 100;
block_entry(1);
break;